Current File : //data/old/home/stash/atlassian/stash/3.7.1/bin/permgen.bat
REM test path to the java executable
if exist "%JAVA_HOME%\jre\bin\java.exe" (
SET javaPath=%JAVA_HOME%\jre\bin
GOTO gotJavaHome
)
if exist "%JAVA_HOME%\bin\java.exe" (
SET javaPath=%JAVA_HOME%\bin
GOTO gotJavaHome
)
if exist "%JRE_HOME%\bin\java.exe" (
SET javaPath=%JRE_HOME%\bin
GOTO gotJavaHome
)
REM Try to find Java on the path
FOR %%i IN (java.exe) DO SET javaPath=%%~dp$PATH:i
if "x%javaPath%"=="x" GOTO finish
REM try to see if it is a JDK or a JRE
SET javaBinDir=%javaPath:~-4%
IF NOT "%javaBinDir%" == "bin\" GOTO :isJRE
SET JAVA_HOME=%javaPath:~0,-5%
GOTO :gotJavaHome
:isJRE
:gotJavaHome
"%javaPath%\java.exe" -version 2>&1 | FINDSTR /c:"java version \"1.6."
IF NOT ERRORLEVEL 1 GOTO finishInvalidJava
"%javaPath%\java.exe" -version 2>&1 | FINDSTR IBM
IF ERRORLEVEL 1 GOTO finish
:finishNoPermGen
exit /b 1
:finishInvalidJava
echo.
echo -------------------------------------------------------------------------------
echo Stash no longer supports Java 1.6. Please upgrade to Java 1.7+
echo -------------------------------------------------------------------------------
exit /b 2
:finish
exit /b 0
Mini Shell